#define Name "Astropolis"
#define VerName "Astropolis 1.0"
#define Company "Autism Collaborative"
#define URL "http://www.autismcollaborative.org/"
#define ExeName "Game.exe"

[Setup]
AppId={{139F9750-16F5-4907-9211-98002879FF54}
AppName={#Name}
AppVerName={#VerName}
AppPublisher={#Company}
AppPublisherURL={#URL}
AppSupportURL={#URL}
AppUpdatesURL={#URL}
DefaultDirName={pf}\{#Company}
DefaultGroupName={#Company}
AllowNoIcons=true
LicenseFile=..\COPYING
OutputDir=.
OutputBaseFilename=AstropolisSetup3
SetupIconFile=..\Game\Game.ico
Compression=lzma/ultra64
SolidCompression=true
InternalCompressLevel=ultra64

[Languages]
Name: english; MessagesFile: compiler:Default.isl

[Tasks]
Name: desktopicon; Description: {cm:CreateDesktopIcon}; GroupDescription: {cm:AdditionalIcons}

[Files]
Source: Dependencies\dotNetFx35.exe; DestDir: {tmp}
Source: Dependencies\xnafx30_redist.msi; DestDir: {tmp}

Source: ..\Game\bin\x86\Release\*; DestDir: {app}; Flags: ignoreversion recursesubdirs createallsubdirs; Excludes: *.pdb, Debug*
Source: ..\Util\bin\x86\Release\*; DestDir: {app}; Flags: ignoreversion recursesubdirs createallsubdirs; Excludes: *.pdb, Debug*
Source: ..\AC_GraphicsEngine\bin\x86\Release\*; DestDir: {app}; Flags: ignoreversion recursesubdirs createallsubdirs; Excludes: *.pdb, Debug*
Source: ..\TACParticleEngine\bin\x86\Release\*; DestDir: {app}; Flags: ignoreversion recursesubdirs createallsubdirs; Excludes: *.pdb, Debug*

Source: ..\ColonySim\bin\x86\Release\*; DestDir: {app}; Flags: ignoreversion recursesubdirs createallsubdirs; Excludes: *.pdb, Debug*, Inpout32.dll
Source: ..\StarJack\bin\x86\Release\*; DestDir: {app}\Minigames\StarJack; Flags: ignoreversion recursesubdirs createallsubdirs; Excludes: *.pdb, Debug*, Inpout32.dll
Source: ..\MaritimeDefender\bin\x86\Release\*; DestDir: {app}\Minigames\MaritimeDefender; Flags: ignoreversion recursesubdirs createallsubdirs; Excludes: *.pdb, Debug*, Inpout32.dll
Source: ..\StellarProspector\bin\x86\Release\*; DestDir: {app}\Minigames\StellarProspector; Flags: ignoreversion recursesubdirs createallsubdirs; Excludes: *.pdb, Debug*, Inpout32.dll
Source: ..\AuditoryStimuli\bin\x86\Release\*; DestDir: {app}\Minigames\AuditoryStimuli; Flags: ignoreversion recursesubdirs createallsubdirs; Excludes: *.pdb, Debug*, Inpout32.dll

[Icons]
Name: {group}\{#Name}; Filename: {app}\{#ExeName}
Name: {group}\{cm:ProgramOnTheWeb,{#Name}}; Filename: {#URL}
Name: {group}\{cm:UninstallProgram,{#Name}}; Filename: {uninstallexe}
Name: {commondesktop}\{#Name}; Filename: {app}\{#ExeName}; Tasks: desktopicon

[Run]
Filename: {tmp}\dotNetFx35.exe; Parameters: /qb
Filename: msiexec.exe; Parameters: "/qb /i ""{tmp}\xnafx30_redist.msi"""
Filename: {app}\{#ExeName}; Description: {cm:LaunchProgram,{#Name}}; Flags: nowait postinstall skipifsilent unchecked